***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 26, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ12B A K
.param
+vc0 = 8.396e-10	 vc1 = 1.585e-10   	 vc2 = 6.362e-1		 vc3 = 1.183e-10	  vc4 = 2.084e-1
+tc1 = 2.551e-2		 tc2 = 1.121e-2		 tc3 = 5.291e-3		 tc4 = 4.671e-3 
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 4.026e-16	   n = 9.994e-1		  rs = 1.511e-1		ikf = 1.845e-1
+ibv = 50e-6		 nbv = 0.8		  bv = 12
***** capacitance parameter *****
+cjo = 7.791e-11	   m = 3.228e-1		  vj = 6.390e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.127		 xti = 3
+trs1 = 1.042e-5	trs2 = 1.057e-6		
+tbv1 = 6.442e-4	tbv2 = 5.005e-8		 tikf = 5.9e-3
.ends PDZ12B
*$
